Chắc chắn các bạn sẽ phải công nhận một điều đó là hình nền hiển thị trên màn hình LockScreen rất đẹp! Tất cả những hình ảnh này đều được chụp từ nhiều nước khác nhau trên thế giới, và Microsoft tập hợp chúng lại tạo thành một bộ sưu tập hình nền dành cho LockScreen trên Windows 10. 

Tuy nhiên, Microsoft lại không cho bạn một cách dễ dàng nào để sử dụng những hình ảnh này làm hình nền desktop cả. Nhưng nếu bạn vẫn muốn dùng những hình ảnh đẹp đẽ này để trang trí cho góc máy tính của mình thì đây sẽ là bài viết dài cho bạn!

Bước 1: Đầu tiên, bạn cần tạo một Notepad bằng cách nhấp chuột phải vào Desktop, chọn New rồi chọn Text Document.

Bước 2: Tiếp theo, bạn copy paste những dòng sau đây vào:

'Copies Spotlight images from Assets folder to "Pictures\Spotlight Collections"
'Picks up only the Landscape images, and having size >250KB.
'Filename: spotlight_collect.vbs © Ramesh Srinivasan - winhelponline.com
'For Windows 10 systems.
'Feel free to modify the script as you need.

Option Explicit
Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject")
Dim WshShell : Set WshShell = WScript.CreateObject("WScript.Shell")
Dim objFolder, oPic
Dim strAssetsFldr, strSpotlightFldr

strAssetsFldr = WshShell.ExpandEnvironmentStrings("%localappdata%") & _
"\Packages\Microsoft.Windows.ContentDeliveryManager_cw5n1h2txyewy\LocalState\Assets"

strSpotlightFldr = WshShell.ExpandEnvironmentStrings("%userprofile%") & _ 
"\Pictures\Spotlight Collection"

If Not objFSO.FolderExists (strSpotlightFldr) Then objFSO.CreateFolder strSpotlightFldr
strSpotlightFldr = strSpotlightFldr & "\"

If objFSO.FolderExists (strAssetsFldr) Then   
   Set objFolder = objFSO.GetFolder(strAssetsFldr)   
   Dim file, iHeight, iWidth
   For Each file In objFolder.Files
      If objFSO.FileExists(strSpotlightFldr & file.Name & ".jpg") <> True _
         And LCase(file.Name) <> "thumbs.db" Then
         If file.Size > 250000 Then
            On Error Resume Next
            Set oPic = LoadPicture(file)
            'Skip pictures that can't be loaded
            If err.number = 0 Then
               iWidth = CInt(round(oPic.width / 26.4583))
               iHeight = CInt(round(oPic.height / 26.4583))
               'Lets copy only Landscape images of size >250KB
               If iHeight < iWidth Then
                  objFSO.CopyFile file, strSpotlightFldr & file.name & ".jpg", False
                  If err.number <> 0 And err.number <> 58 Then
                     WScript.Echo err.number & vbCrLf & err.Description
                  End If
               End If
            End If
            On Error GoTo 0
         End If
      End If
   Next
End If

Bước 3: Sau đó, bạn lưu file Notepad lại, đặt tên cho nó là wallpaper.vbs và ở Save as type bạn chọn All files. 

Sau đó bạn tạo một thư mục mới, đặt tên bất kỳ và bỏ file Notepad vào trong.

Bước 4: Bạn nhấp chuột vào file Notepad, rồi bấm mục Home và chọn Copy path để copy đường dẫn của file Notepad này.

Bước 5: Tiếp theo, bạn bấm vào Windows và gõ Command Prompt rồi chọn Run as administrator.

Bước 6: Bạn thay chữ A ở cuối dòng lệnh dưới đây bằng đường dẫn mà bạn đã copy ở bước 4.

SCHTASKS /create /SC HOURLY /MO 6 /TN “Save Spotlight Images” /TR “wscript.exe A”

Bạn lưu ý xóa bớt ký tự “” xuất hiện sau khi thay vào A và để ý rằng ký tự “ có bị đổi font không, nếu có thì bạn đổi lại thành “ như hình bên dưới nhé. Các bạn có thể thử bằng cách paste vào Notepad.

Bước 7: Sau khi thay xong thì bạn copy và paste vào Command Prompt rồi Enter. Nếu hiện chữ SUCCESS tức là bạn thành công.

Bước 8: Tiếp tục, bạn copy và paste dòng sau đây vào Command Prompt rồi Enter. 

schtasks /Run /TN “Save Spotlight Images”

Và cũng tương tự như bước 6, bạn kiểm tra xem ký tự “ có bị đổi font không nhé!

Nếu hiện chữ SUCCESS là bạn đã kích hoạt tính năng lấy ảnh LockScreen thành công.

Bước 9: Tiếp theo bạn bấm vào Windows và gõ Task Scheduler rồi Enter.

Bước 10: Chọn Task Scheduler Library rồi nhấn đúp vào Save Spotlight… để mở nó lên.

Bước 11: Một cửa sổ mới hiện lên, bạn chọn mục Settings rồi chọn ô Run task as soon as possible after a scheduled start is missed rồi chọn OK.

Sau khi hoàn thành xong, trong thư mục Pictures của Windows sẽ xuất hiện một thư mục Spotlight Collection. Thư mục này sẽ có vai trò sưu tập tất cả các hình nền LockScreen sau mỗi 6 tiếng (tương ứng với mỗi 6 tiếng Windows sẽ đổi hình nền LockScreen một lần).

Sau khi sưu tập đủ bộ thì bạn có thể chọn hình nền mà bạn muốn để làm hình nền Desktop hoặc tạo Slideshow để Windows tự động thay đổi hình ảnh sau 1 phút.

Xem thêm: Hướng dẫn sử dụng Slideshow thay đổi hình nền tự động trên Windows 10.

Vậy là mình đã hướng dẫn xong cho các bạn cách sử dụng hình nền LockScreen làm hình nền Desktop. Chúc các bạn thành công!